/*
 ================================================
 Driver coils and guide patterns in bubble memory
 ------------------------------------------------
 Created by Søren Peo Pedersen - see my user page
 at http://da.wikipedia.org/wiki/Bruger:Peo
 ================================================
 */
 
 #declare MagnetFont="arialbd.ttf" // Font for the "N" and "S" nomenclature on magnets
 #declare NorthLtr="N";  // Letter to indicate north pole
 #declare SouthLtr="S";  // Letter to indicate south pole
 
 box {<-4,-.3,-4>,<4,.3,4> // The orthomagnetic sheet, this time with
   pigment {               // no domains; only a single gradient indi-
     gradient y            // cating magnetization oriented in accor-
     color_map {           // dance with the external field.
       [0.0 color rgb <1,0,0>]
       [1.0 color rgb <1,1,1>]
       }
     scale .602
     translate -.301
     }
   finish {ambient .5}
   }
 
 // Magnets to "squeeze" bubbles down in size:
 box {<-4,3.5,-4>,<4,30,4> // The north pole above the sheet
   pigment {
     object {
       text {ttf MagnetFont,NorthLtr,3,0 // with the nomenclature
         scale 10 translate <-3,4,-30>   // for "north" on the side
         }
 
       pigment {color rgbt <1,0,0,.8>}
       pigment {color rgbt <1,1,1,.8>}
       }
     }
   finish {ambient .5}
   }
 
 box {<-4,-79,-4>,<4,-4.5,4> // The south pole below the sheet
   pigment {
     object {
       text {ttf MagnetFont,SouthLtr,3,0 // with the nomenclature
         scale 10 translate <-3,-12,-30> // for "south" on the side
         }
       pigment {color rgbt <1,1,1,.8>}
       pigment {color rgbt <1,0,0,.8>}
       }
     }
   finish {ambient .5}
   }
 
 #macro Coilset(Width,CoilColor) // One set of coil windings, with arbitrary "thickness" and color
   #local n=0;  // Loop that sets up several windings in the coil
   merge {
     #while (n<5) // 5 windings to be exact...
       // Straight parts of winding; the ends extending "out" from the coil:
       cylinder {<#if (n=4) -10 #else -4 #end,Width/2,1.6*n-2.8>,<4,Width/2,1.6*n-2.8>,.03}
       cylinder {<#if (n=0) -10 #else -4 #end,-Width/2,1.6*n-3.6>,<4,-Width/2,1.6*n-3.6>,.03}
       difference {  // Curved parts around the edges,
         torus {sqrt(.64+Width*Width)/2,.03} // made with a torus, ...
         plane {<1,0,0>,0}                   // whith half of it cut off.
         rotate <-degrees(atan(Width/.8)),0,0>
         translate <4,0,1.6*n-3.2>
         }
       #if (n>0) // Omit one curved segment at one end of the coil, else...
         difference {  // add a curved part around the opposing edge
           torus {sqrt(.64+Width*Width)/2,.03} // also made with a torus
           plane {<-1,0,0>,0}                  // with one half cut off.
           rotate <degrees(atan(Width/.8)),0,0>
           translate <-4,0,1.6*n-4>
           }
       #end      
       #local n=n+1;
     #end
     pigment {color CoilColor} // Apply specified color
     finish {ambient .5}
     }
 #end
 
 // The two coils wound around the orthomagnetic sheet:
 #object {Coilset(1.5,<0,.5,1>)}                   // Blue coil
 #object {Coilset(1.7,<1,.7,0>) rotate <0,90,0>}   // Yellowish coil
 
 #declare Tguide=merge {  // T-shaped guide piece:
   cylinder {<-.5,.3,.5>,<.5,.3,.5>,.03}    // Lots of cylinders and spheres
   sphere {<.5,.3,.5>,.03}                  // to provide nice, smooth corners
   cylinder {<.5,.3,.5>,<.5,.3,.3>,.03}     // and edges
   sphere {<.5,.3,.3>,.03}
   cylinder {<.5,.3,.3>,<.1,.3,.3>,.03}  
   cylinder {<.1,.3,.3>,<.1,.3,-.5>,.03}
   sphere {<.1,.3,-.5>,.03}
   cylinder {<.1,.3,-.5>,<-.1,.3,-.5>,.03}
   sphere {<-.1,.3,-.5>,.03}
   cylinder {<-.1,.3,.3>,<-.1,.3,-.5>,.03}
   cylinder {<-.5,.3,.3>,<-.1,.3,.3>,.03}
   sphere {<-.5,.3,.3>,.03}
   cylinder {<-.5,.3,.5>,<-.5,.3,.3>,.03}  
   box {<-.5,0,.3>,<.5,.33,.5>}
   box {<-.1,0,-.5>,<.1,.33,.3>}
   pigment {color rgb .5}       // Medium grey color
   finish {ambient .5 phong 1}  // Soft shadows, plus specular highlights
   }
 
 #declare Iguide=merge {   // I-shaped guide piece:
   cylinder {<-.1,.3,.5>,<.1,.3,.5>,.03}   // A rectangular slab framed
   sphere {<.1,.3,.5>,.03}                 // by spheres and cylinders for
   cylinder {<.1,.3,.5>,<.1,.3,-.5>,.03}   // smooth corners and edges.
   sphere {<.1,.3,-.5>,.03}
   cylinder {<.1,.3,-.5>,<-.1,.3,-.5>,.03}  
   sphere {<-.1,.3,-.5>,.03}
   cylinder {<-.1,.3,-.5>,<-.1,.3,.5>,.03}
   sphere {<-.1,.3,.5>,.03}
   box {<-.1,0,-.5>,<.1,.33,.5>}
   pigment {color rgb .5}
   finish {ambient .5 phong 1}
   }
 
 #local Row=0;   // Row loop for placing guide pieces on the orthomagnetic sheet
 #while (Row<3)  // Three rows, or "tracks"
   #local Col=0;     // Column loop for four repetitions of the guide piece pat-
   #while (Col<4)    // tern along each track:
     #object {Tguide translate <1.6*Col-3.2,0,Row*2.4-3>}
     #object {Iguide translate <1.6*Col-2.4,0,Row*2.4-2.2>}
     #local Col=Col+1;
   #end
   #object {Tguide translate <3.2,0,Row*2.4-3>}  // Add an extra "T" at the end
   #local Row=Row+1;
 #end
 
 background {color rgb 1} // White background
 
 camera { // View the motif ...
   location <6,4,-8>  // ... from this vantage point, ...
   look_at <-.7,0,0>  // ... looking towards this point.
   }
 
 light_source {     // Light source
   <-100,150,-120>
   color rgb 1
   }