Datei:COVID-19-Pandemie - DE (Deutschland) - Infizierte (1200px).svg
Größe der PNG-Vorschau dieser SVG-Datei: 800 × 300 Pixel. Weitere aus SVG automatisch erzeugte PNG-Grafiken in verschiedenen Auflösungen: 320 × 120 Pixel | 640 × 240 Pixel | 1.024 × 384 Pixel | 1.280 × 480 Pixel | 2.560 × 960 Pixel | 1.200 × 450 Pixel
Originaldatei (SVG-Datei, Basisgröße: 1.200 × 450 Pixel, Dateigröße: 182 KB)
Diese Datei und die Informationen unter dem roten Trennstrich werden aus dem zentralen Medienarchiv Wikimedia Commons eingebunden.
_-_Infizierte_(1200px).svg?uselang=de){kind=small}
Beschreibung
| Beschreibung | COVID-19-Pandemie - DE (Deutschland) - Infizierte (1200px) | ||
| Datum | laufende Aktualisierungen | ||
| Quelle | Daten von der WHO - https://covid19.who.int/WHO-COVID-19-global-data.csv - durch Klicken auffindbar über https://covid19.who.int/table | ||
| Urheber | Summer ... hier! | ||
| SVG‑Erstellung |  Diese Vektorgrafik wurde mit Gnuplot erstellt.  Diese Datei verwendet Text-Einbettung. | ||
| Quelltext | Gnuplot code# input (Zeitformat und Separator definieren)
#
set timefmt "%Y-%m-%d"
set datafile separator ';'
# Variablen zeile_X_stat setzten
# (every ::0 steht für 'ab erster Zeile' und kann weggelassen werden)
stats $WHO_data every ::0 using 5 name "zeile_5_stat" nooutput
stats $WHO_data every ::0 using 6 name "zeile_6_stat" nooutput
stats $WHO_data every ::0 using 7 name "zeile_7_stat" nooutput
stats $WHO_data every ::0 using 8 name "zeile_8_stat" nooutput
# Start und Ende ermitteln und Label setzen (incl. Konsolenausgabe)
stats $WHO_data every ::0 u (strptime("%Y-%m-%d",strcol(1))) name "datum" nooutput
print ' -----Stats-(Timestamp)----'
print ' Start: ', strftime("%d. %B %Y",datum_min)
print ' Ende: ', strftime("%d. %B %Y",datum_max)
print ' --------------------------'
# label fuer Grafikueberschrtft oben links mit den ermittelten Werten setzen
set label 'Daten vom '.strftime("%d.%m.%y",datum_min).' bis '.strftime("%d.%m.%y",datum_max) at graph 0.03, graph 0.93
# als Workaround nehmen wir statt zweimal 'ylabel' hier zweimal 'label'
# (bei multiplot ist es schwierig fuer alle Plots ein ylabel mit gleichen seitl. Einzug zu finden)
set label "Infizierte (kumuliert)" at screen 0.017, 0.700 rotate by +90 center
set label "Neuinfektionen" at screen 0.017, 0.300 rotate by +90 center
# output
#
# Name der SVG-Datei
set output 'COVID-19-Pandemie_-_DE_(Deutschland)_-_Infizierte_(1200px).svg'
unset key # keine Box fuer Legende
set border 3 # Rahmen unten (Bit 1) und links (+ Bit 2)
set xtics scale 0.7 0.4 # Skalenstriche x-Achse etwas kleiner
set ytics scale 0.7 0.4 # Skalenstriche y-Achse etwas kleiner
# Gitterlinienen per Hand setzen
set style line 1 linetype rgb '#4F4F4F' linewidth 0.25 # Def. Major-grid
set style line 2 linetype rgb '#9F9F9F' linewidth 0.20 # def. Minor-grid
unset grid
set grid noxtics nomxtics # Keine Gitterlinen an der 1. X-Achse (Monate)
set grid x2tics nomx2tics # Gitterliniene an der 2. X-Achse (Kalenderwochen)
set grid ytics mytics # Gitterl. an der Y-Achse
set grid back # Gitter im Hintergrund
set grid linestyle 1, linestyle 2 # Setzen des linestyle fuer Major u. Minor
# X-Achsenbeschriftung:
# ueber x1 machen wir die Monatsbschriftung, ueber x2 die Kalenderwochenbeschriftung
#
# beide X-Achsen, also x1 und x2, als Zeitachse definieren
set xdata time
set x2data time
# Bereich (von - bis) der X-Achse definieren
# Beginnt am 1. Jan. 2020 und Edit heute plus 6 Tage
xrange_max=strftime("%Y-%m-%d", time(0) + (60*60*24*6))
# zuvor Berechnetes xrange_max setzten
set xrange ['2020-01-01': xrange_max]
set x2range ['2020-01-01': xrange_max]
# die Maker fuer Monat setzen wir per Hand. Als 'format' geben wir einen leeren String an damit
# kein Text generiert wird (fuer die untere Grafik setzen wir den Text spaeter)
set xtics format "" # Format auf Nichts damit gnuplot die folgenden Daten nicht aufloest
set xtics ( "2020-01-01" \
, "2020-02-01" \
, "2020-03-01" \
, "2020-04-01" \
, "2020-05-01" \
, "2020-06-01" \
, "2020-07-01" \
, "2020-08-01" \
, "2020-09-01" \
, "2020-10-01" \
, "2020-11-01" \
, "2020-12-01" \
, "2021-01-01" \
, "2021-02-01" \
, "2021-03-01" \
)
#
# Kalenderwochen-Striche
#
# fuer x2 (KW) ebenfalls keine Beschriftung
set format x2 ''
# der 6. Jan. 2020 war ein Montag - da setzen wir den ersten Strich und die
# folgenden Striche alle 7 Tage (hier in 60 * 60 * 24 * 7 Sekunden)
set x2tics '2020-01-06', 60 * 60 * 24 * 7
set x2tics scale 0
set xtics nomirror
unset mxtics
# Format Y-Achse
set decimalsign locale "de_DE.utf8"
set format y "%'.0f"
set yrange [-50000:*]
set ytics 250000
set mytics 5
set ytics nomirror
# Zebramuster
set style rect fillcolor lt -1 fillstyle solid 0.06 noborder
do for [i=1:12:2] {
marker_start=sprintf("2020-%1.2d-01",i)
marker_stop =sprintf("2020-%1.2d-01",i+1)
print 'setze grauen Marker: ' . marker_start . "-" . marker_stop
set object rectangle from marker_start,graph 0 to marker_stop, graph 1
}
# Groesse und Schrift definieren
#
# Zur Variablen 'datum_max' siehe oben
my_svg_name=strftime("COVID_%d_%m_%Y",datum_max)
set term svg size 1200,450 font "Arial,16" name my_svg_name
###########################################################################################
set lmargin 10.0 # linker Rand fuer Beschriftung Y-Achse sollte nicht auf Auto stehen
set rmargin 1.0 # rechter Rand
set tmargin 1.0 # top margin
set bmargin 0.0 # bottom margin
set multiplot
# Ausgabe oberer Graph
set size 1.000, 0.550 # Groesse der Grafik
set origin 0.000, 0.450 # def. der linken unteren Ecke
unset xlabel
plot $WHO_data usi 1:6 axis x1y1 tit 'Infizierte' lt rgb '#DF7000' lw 1.75 with lines
# Ausgabe unterer Graph
set tmargin 0.4 # Wert von oben ueberschreiben damit Grafiken enger zusammen
unset bmargin # oben wurde bottommargin auf null gesetzt - jetzt wieder auto damit Platz fuer Skala
unset label #
set size 1.000, 0.450
set origin 0.000, 0.000
# Wenn das Datumsintervall so gross wird das die Labels zu eng gesetzt sind
# hier jeden zweiten Eintrag loeschen!
set xtics rotate by +30 center offset -1.5,-0.6
set xtics add ( "1. Jan." "2020-01-01" \
, "1. Feb." "2020-02-01" \
, "1. März" "2020-03-01" \
, "1. Apr." "2020-04-01" \
, "1. Mai" "2020-05-01" \
, "1. Jun." "2020-06-01" \
, "1. Jul." "2020-07-01" \
, "1. Aug." "2020-08-01" \
, "1. Sep." "2020-09-01" \
, "1. Okt." "2020-10-01" \
, "1. Nov." "2020-11-01" \
, "1. Dez." "2020-12-01" \
, "1. Jan. 21" "2021-01-01" \
, "1. Feb." "2021-02-01" \
, "1. März" "2021-03-01" \
)
set xlabel "Datum (Monats- und KW-Skala)"
set yrange [-1000:*]
set ytics 5000
set mytics 5
# Ueber den Wert von lw kann man die Sichtbarkeit bei kl. Aufl. regulieren
plot $WHO_data usi 1:5 axis x1y1 tit '' lt rgb '#DF7000' lw 0.75 with impulses
unset multiplot
Gnuplot data code
|
_-_Infizierte_(1200px).svg){kind=link}
_-_Infizierte_(1200px).svg&action=edit&redlink=1){kind=link}
Lizenz
Ich, der Urheber dieses Werkes, veröffentliche es unter der folgenden Lizenz:
 
|
Diese Datei wird unter der Creative-Commons-Lizenz „CC0 1.0 Verzicht auf das Copyright“ zur Verfügung gestellt. |
| Die Person, die das Werk mit diesem Dokument verbunden hat, übergibt dieses weltweit der Gemeinfreiheit, indem sie alle Urheberrechte und damit verbundenen weiteren Rechte – im Rahmen der jeweils geltenden gesetzlichen Bestimmungen – aufgibt. Das Werk kann – selbst für kommerzielle Zwecke – kopiert, modifiziert und weiterverteilt werden, ohne hierfür um Erlaubnis bitten zu müssen.
|
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
| Version vom | Vorschaubild | Maße | Benutzer | Kommentar | |
|---|---|---|---|---|---|
| aktuell | 10:47, 17. Jan. 2021 | | 1.200 × 450 (182 KB) | Summer ... hier! | update |
Dateiverwendung
Die folgende Seite verwendet diese Datei:
_-_Infizierte_(1200px).svg){kind=link}