Diese Seite ist eine Sammlung von SPARQL-Abfragen nach Informationen, die für die Physik-Redaktion von Interesse sein könnten. Eine Abfrage kann mit Copy und Paste in das Suchanfragefeld auf query.wikidata.org kopiert werden und nachdem Start der Suche die Ergebnis-Listen dort angesehen werden. Beachte: Suchanfragen die länger als 60 s dauern werden mit einem Zeitfehler abgbrochen. Etwaige Wünsche für weitere Abfragen können gerne auf der Diskussionsseite gestellt werden.
Jahrestage
BearbeitenZur Pflege des Kalenders der Jahrestage ist ein Abgleich mit den bei Wikidata hinterlegten Geburts- und Todestage von Physikern/Physikerinnen sinnvoll. Dazu hilft eine Abfrage wie diese, mit der ab einem einzugebenden Kalendertag die entsprechenden Daten gezogen werden können.
Es ist dabei jedoch zu beachten, dass wir im Kalender der Jahrestage nicht alle Physiker/Physikerinnen auflisten können, die in Wikidata vorkommen. Der in der Abfrage vorkommende LinkCount (also die Anzahl von Links innerhalb von Wikidata auf das Wikidata-Item der betrachteten Person), sowie die unten unter #Auswahlkriterien genannten Punkte sind Hilfestellungen, können aber eine editorielle Auswahl nicht ersetzen.
| Wikidata-Code der obigen Abfrage |
|---|
SELECT DISTINCT ?physicist ?sitelink_de ?date_of_birth ?date_of_death ?linkcount ?monthdate
WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
?physicist wdt:P106/wdt:P279* wd:Q169470.
?sitelink_de schema:isPartOf <https://de.wikipedia.org/>;
schema:about ?physicist.
OPTIONAL { ?physicist wdt:P569 ?date_of_birth. }
OPTIONAL { ?physicist wdt:P570 ?date_of_death. }
OPTIONAL { ?physicist wikibase:sitelinks ?linkcount.}
OPTIONAL { ?physicist wdt:P569 ?date. } # hier P569 für Geburtstage, P570 für Todestage verwenden
BIND ( 100*MONTH(?date) + DAY(?date) AS ?monthdate )
FILTER (?monthdate >=919 ) # hier das Datum, ab dem überprüft werden soll im Format "Mdd" eingeben
}
ORDER BY ?monthdate DESC(?linkcount) ?physisttLabel
LIMIT 100
Es sind dann je nach Wunsch in den entsprechend kommentierten Zeilen
|
Suche nach Physiker und Ordnung nach Geburtstag
Bearbeiten## Frage nach Physiker, die eine Seite auf de.wiki und en.wiki haben, und ordne
# das Datum nach dem Geburtstag im Jahr
#
#SELECT ( COUNT(?item) as ?numberOfPhysicists ) # result 4981 (in 28s) at 2019-09-08
#
SELECT DISTINCT ?item ?itemLabel ?sitelink (YEAR(?date) as ?year) ?date
WHERE
{
?item wdt:P106/wdt:P279* wd:Q169470. # Tätigkeit '?classPhys', mit "property path" S 62-65
?sitelink schema:isPartOf <https://de.wikipedia.org/>;
schema:about ?item.
?site2link schema:isPartOf <https://en.wikipedia.org/>;
schema:about ?item.
?item wdt:P569 ?date .
BIND( 100*MONTH(?date) + DAY(?date) AS ?monthday )
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?monthday
LIMIT 6000
Ein ?item muss die Eigenschaft (P106) – ist/war tätig als "Physiker" (Q169470) (oder eine der Unter(*)klassen (P279) davon) – haben. Weiter muss für ?item eine Seite in de.wikipedia.org und en.wikipedia.org existieren. Die Ergebnis-Liste wird nach dem Geburtstag geordnet. Sie enthält die Spalten ?item, seinen Label, die URL zu Seite in de.wikipedia, das Geburtsjahr und das Geburtsdatum (wdt:P569). Achtung: Zum 1. Januar gibt es wohl mehr als 500 Einträge, vermutlich weil Personen, für die nur ein Geburtsjahr angegeben wurde, fälschlich der Geburtstag 1.1. zugeordnet wird!
Suche nach gestorbenen Physiker und Ordnung nach Todestag
BearbeitenDiese Abfrage kann aus der obigen Abfrage für die Geburtstage gewonnen werden, in dem man die Zeile
?item wdt:P569 ?date .
durch
?item wdt:P570 ?date .
ersetzt.
Auswahlkriterien
BearbeitenDie im folgenden genannten Abfragen sollen als Hilfestellung bei der Frage dienen, ob eine bestimmte Person wirklich in den Kalender aufgenommen werden soll.
Suche nach den Ehrungen einer Person
Bearbeiten## Frage nach der Ehrungen/Preisen einer Person
#
SELECT DISTINCT ?item ?itemLabel ?award ?awardLabel
WHERE
{
BIND ( wd:Q41257 AS ?item ) # <= here, replace the Wikidata-Id
# Q41257 of Heinrich Hertz by the
# Wikidata-Id of the person you are interested in.
?item wdt:P166 ?award .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?awardLabel
LIMIT 250
In der Abfrage muss jeweils die Wikidata-ID Q41257 von Heinrich Hertz durch die der Person, für die man sich interessiert, ersetzt werden.
Um in der Liste der Geburtstage oder Todestage die Nobelpreisträger in Physik herauszufiltern, kann man z.B. folgenden Filter verwenden:
OPTIONAL { ?physicist wdt:P166 ?award.}
FILTER ( ?award = wd:Q38104 )
Suche nach Objekten die nach dem Namen einer Person benannt wurden
Bearbeiten## Frage nach Objekten, die nach dem Namen einer Person benannt wurden
#
SELECT DISTINCT ?item ?itemLabel ?objNamed ?objNamedLabel
WHERE
{
BIND ( wd:Q41257 AS ?item ) # <= = here replace the Wikidata-Id
# Q41257 of Heinrich Hertz by the
# Wikidata-Id of the person you are interested in.
?objNamed wdt:P138 ?item .
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?objNamedLabel
LIMIT 250
In der Abfrage muss jeweils die Wikidata-ID Q41257 von Heinrich Hertz durch die der Person, für die man sich interessiert, ersetzt werden.